Fichièr:Hyperbolic orbit.gif

Lo contengut de la pagina non es disponible dins una autra lenga.
Un article de Wikipèdia, l'enciclopèdia liura.

Hyperbolic_orbit.gif ‎(300 × 300 pixèl, talha del fichièr: 12 Ko, tipe MIME: image/gif, en bocla, 90 imatges, 4,2 s)

 
Aqueste imatge es estat creat amb Persistence of Vision.
a Semimajor axis
rp Periapsis' Radius
υ∞ Divergence angle

Descripcion

Descripcion Animation showing the motion of a small body (green) in an hyperbolic orbit around a much more massive body (blue).
Data
Font Own work. Rendered with PovRay-3.0, animated with gifsicle.
Autor Brandir
Permission
(Reütilizacion d'aqueste fichièr)		 Brandir put it under the GFCL and the CC-BY-SA

Publicat jos licéncia(s)

Ieu, autor d'aquesta òbra, publiqui jos las licéncias seguentas:
GNU head Avètz la permission de copiar, distribuir e modificar aqueste document segon los tèrmes de la Licéncia de documentacion liura GNU, version 1.2 o mai recenta publicada per la Free Software Foundation; sens seccions inalterablas, sens tèxte de primièra pagina de tempa e sens tèxte de darrièra pagina de tempa. Un exemplar de la licéncia es inclús dins la seccion intitulada GNU Free Documentation License.
w:oc:Creative Commons
atribucion partiment a l'identic 		Aqueste fichièr es jos licéncia Creative Commons licéncia generica atribucion-partiment a l'identic 3.0
Sètz liure :
  • de partejar – de copiar, distribuir e transmetre aquesta òbra
  • d'adaptar – d'adaptar aquesta òbra
Jos las condicions seguentas :
  • atribucion – Vos cal atribuir aquesta òbra amb lo biais especificat per l'autor o lo concedent (mas pas dins un sens que suggerís que vos apròvan o qu'apròvan l'utilizacion d'aquesta òbra).
  • partiment a l'identic – Se modificatz, transformatz, o vos basatz sus aquesta òbra, vos cal distribuir l'òbra resultanta jos la meteissa licéncia o una licéncia similara a aquesta.
Aquest avís de llicència s'ha afegit a aquest fitxer d'acord amb l'actualització de la llicència GFDL.
w:oc:Creative Commons
atribucion partiment a l'identic
Aquest fitxer està publicat sota la llicència de Creative Commons Reconeixement i Compartir Igual 2.5 Espanya.
Sètz liure :
  • de partejar – de copiar, distribuir e transmetre aquesta òbra
  • d'adaptar – d'adaptar aquesta òbra
Jos las condicions seguentas :
  • atribucion – Vos cal atribuir aquesta òbra amb lo biais especificat per l'autor o lo concedent (mas pas dins un sens que suggerís que vos apròvan o qu'apròvan l'utilizacion d'aquesta òbra).
  • partiment a l'identic – Se modificatz, transformatz, o vos basatz sus aquesta òbra, vos cal distribuir l'òbra resultanta jos la meteissa licéncia o una licéncia similara a aquesta.
Podètz causir la licéncia que volètz.

POV-Ray Scene description

POV-ray image description: 

 /*
 --------------------------
 Hyperbolic Orbit Animation
 --------------------------
 Created 7 Mar. 2006
 */
     
 #include "colors.inc"
 
 //Orbit Definition
 #declare OrbitA=30;
 #declare OrbitE=1.38;
 
 //Scene Constants
 #declare EarthRadius=6.356;
 #declare SatRadius=1.2;
 #declare OrbitWidth=0.5;
 #declare LineWidth=0.5/3;
 #declare Crosslength=1.5;
 #declare Textscale=9;
 #declare TextColor=rgb<0,0,0>;
 #declare xinit=-35;
 
 //Variables
 #declare Minit=OrbitE*sinh(acosh(-(xinit/OrbitA-OrbitE)))-acosh(-(xinit/OrbitA-OrbitE));
 #declare M=Minit-2*clock*Minit;
 #declare PI=3.14159265359;
 #declare Angleinf=180-acos(-1/OrbitE)*(180/PI);
 
 //Anomaly Determination - Solves the equation M=e*sinh(H)-H by the iterative method
 #declare Index=0;
 #declare prevAnomaly=0;
 #declare Anomaly=0;
 #while (Index<30)
     #declare Anomaly=asinh((M+prevAnomaly)/OrbitE);
     #declare prevAnomaly=Anomaly;
     #declare Index=Index+1;
 #end
 
 //General settings
 global_settings{
     ambient_light 1
     }
 
 light_source { <-50, 0, -70> color White }
 
 camera {
   orthographic
   location <-10, 0, -10>
   look_at  <-10, 0,  0>
   up <0,100,0>
   right <100,0,0>
 }
 
 
 plane { <0, 0, 1>, 8
     pigment {White}
     finish{ambient 1 brilliance 0}
 }
 
 
 //Earth
 sphere {
     <0, 0, 0>, EarthRadius
     pigment { Blue }
     finish{ ambient 0.3 brilliance 1.2 diffuse 0.8}
 }
 
 
 //Orbit
 intersection{
     box{
         <-100,-100,-OrbitWidth>, <100,100,OrbitWidth> 
     }
     quadric{
         <1/(OrbitA*OrbitA),-1/(OrbitA*OrbitA*(OrbitE*OrbitE-1)),0>,<0,0,0>,<2*OrbitE/OrbitA,0,0>,OrbitE*OrbitE-1
         translate x*OrbitWidth/2
     }
     quadric{
         <-1/(OrbitA*OrbitA),1/(OrbitA*OrbitA*(OrbitE*OrbitE-1)),0>,<0,0,0>,<-2*OrbitE/OrbitA,0,0>,1-OrbitE*OrbitE
         translate -x*OrbitWidth/2
     }
     pigment{ rgb<0.8,0,0> }
     finish{ ambient 1 brilliance 0 diffuse 0}
     rotate 2.2*y
     no_shadow
 }
 
 
 //Satellite
 sphere {
     <0, 0, -10>, SatRadius
     pigment { SeaGreen }
     finish{ ambient 1 brilliance 0 diffuse 0}
     no_shadow
     translate <-OrbitA*(OrbitE-cosh(Anomaly)),OrbitA*sqrt(OrbitE*OrbitE-1)*sinh(Anomaly),0>
 }
 
 //Lines
 #declare crossBars=
 object{
     union{
         box{
             <-LineWidth,-Crosslength,-LineWidth-7>, <LineWidth,Crosslength,LineWidth-7> 
         }
         box{
             <-Crosslength,-LineWidth,-LineWidth-7>, <Crosslength,LineWidth,LineWidth-7>
         }
         rotate z*45
         pigment{ TextColor }
         finish{ ambient 1 brilliance 0 diffuse 0}
         no_shadow
     }
 }
 
 box{
     <-OrbitA*OrbitE-3,-LineWidth,-LineWidth-7>, <0,LineWidth,LineWidth-7> 
     pigment{ TextColor }
     finish{ ambient 1 brilliance 0 diffuse 0}
     no_shadow
 }
 
 box{
     <0,-LineWidth,-LineWidth-7>, <300,LineWidth,LineWidth-7> 
     pigment{ TextColor }
     finish{ ambient 1 brilliance 0 diffuse 0}
     rotate z*Angleinf
     translate -x*OrbitA*OrbitE
     no_shadow
 }
 
 box{
     <0,-LineWidth,-LineWidth-7>, <300,LineWidth,LineWidth-7> 
     pigment{ TextColor }
     finish{ ambient 1 brilliance 0 diffuse 0}
     rotate -z*Angleinf
     translate -x*OrbitA*OrbitE
     no_shadow
 }
 
 difference{
     torus{
         4,LineWidth
         rotate x*90
     }
     box {
         <-5,0,-5>,<5,5,5>
     }
     box {
         <-5,-5,-5>,<5,0,5>
         rotate -z*Angleinf
     }
     pigment{ TextColor }
     finish{ ambient 1 brilliance 0 diffuse 0}
     translate -z*7
     translate -x*OrbitA*OrbitE
     no_shadow
 }
 
 object{
     crossBars
 }
 
 object{
     crossBars
     translate -x*OrbitA*(OrbitE-1)
 }
 
 object{
     crossBars
     translate -x*OrbitA*OrbitE
 }
 
 //Text
 text {
     ttf "timesi.ttf" "a" 1, 0
     pigment{ TextColor }
     finish{ ambient 1 brilliance 0 diffuse 0}
     scale Textscale
     translate <OrbitA*(0.5-OrbitE)-Textscale/4,Textscale/4,-7>
     no_shadow
 }
 
 union{
     text {
         ttf "timesi.ttf" "r" 1, 0
     }
     text {
         ttf "timesi.ttf" "p" 1, 0
         scale 0.5
         translate 0.2*x
     }
     pigment{ TextColor }
     finish{ ambient 1 brilliance 0 diffuse 0}
     scale Textscale
     translate <-(EarthRadius+0.3*(OrbitA*(OrbitE-1)-EarthRadius))-Textscale/4,Textscale/4,-7>
     no_shadow
 }
 
 union{
     text {
         ttf "symbol.ttf" "u" 1, 0
         matrix 
             < 1, 0, 0,
             0.3, 1, 0,
             0, 0, 1,
             0, 0, 0 >
     }
     text {
         ttf "symbol.ttf" chr(165) 1, 0
         scale 0.5
         translate <0.6,-0.1,0>
     }
     pigment{ TextColor }
     finish{ ambient 1 brilliance 0 diffuse 0}
     scale Textscale
     translate <-OrbitA*OrbitE-Textscale/4+9,-0.6*Textscale,-7>
     no_shadow
 }

Llegendes

Afegeix una explicació d'una línia del que representa aquest fitxer

Elements representats en aquest fitxer

subjècte representat

tipus de mèdia d'Internet catalan

image/gif

Istoric del fichièr

Clicar sus una data e una ora per veire lo fichièr tal coma èra a aqueste moment

Data e oraMiniaturaDimensionsUtilizaireComentari
actual8 març de 2006 a 00.01Miniatura per la version del 8 març de 2006 a 00.01300×300 (12 Ko)Brandir~commonswiki{{Information| |Description = Animation showing the motion of a small body (green) in an hyperbolic orbit around a much more massive body (blue). |Source = Own work. Rendered with ''PovRay-3.0'', animated with ''gifsicle''. |Date = Created 7. Mar. 2006.

La pagina çaijós compòrta aqueste imatge :

Usatge global del fichièr

Recuperada de « https://oc.wikipedia.org/wiki/Fichièr:Hyperbolic_orbit.gif »